CAC 40 : 15/02/2024 Le coin des ATistes ép 6 : Williams, Aroon, ATR, SuperTrend

sar_rabindranath

09 avril 2025 •11:08

Aroon : indicateur de tendance
Développé par Tushar Chande en 1995, Aroon est un indicateur de tendance borné de 0 à 100.

Composé de deux lignes, « Aroon Up » et « Aroon Down ».
Le système « Aroon » mesure, en pourcentage, le temps qui s'est écoulé depuis le plus haut/plus bas sur la durée de calcul de l’indicateur, généralement 14 jours.

Quand une valeur fait un PH de 14 jours, son Aroon Up vaut 100.
Quand la valeur marque un PB de 14 jours, son Aroon Down vaut 100
Quand une valeur n’a pas fait de nouveau PH en 14 jours, son Aroon Up vaut 0.
Quand une valeur n’a pas fait un nouveau PB en 14 jours, son Aroon Down vaut 0.
Un troisième indicateur appelé « Aroon oscillator » est obtenu en soustrayant Aroon Down de Aroon Up
Méthode de Calcul

AroonUp = [(Période de calcul – Nb. de hausses sur la période) / Période] * 100
AroonDown = [(Période de calcul - Nb. de baisses sur la période) / Période] * 100;
Nb. de hausses = nombre de séances où le plus haut est supérieur au plus haut en n-1
Nb. de baisses = nombre de séances où le plus bas est inferieur au plus bas en n-1
Aroon_Oscillator = AroonUp - AroonDown
Excel : 8 colonnes de DL à DS

Constante : DL3=14
DL : max ph
=MAX(DECALER(C10971;-$DL$3;0):C10971)
DM : min pb
=MIN(DECALER(D10971;-$DL$3;0):D10971)
DN : nb
jmax
=SIERREUR($DL$3-EQUIV(DL10971;(DECALER(C10971;-$DL$3+1;0):C10971);0);14)
DO : aroonup
=($DL$3-DN10971)/$DL$3*100
DP : nb
jmin
=SIERREUR($DL$3-EQUIV(DM10971;(DECALER(D10971;-$DL$3+1;0):D10971);0);14)
DQ : aroondown
=($DL$3-DP10971)/$DL$3*100
DR : diff aroon
=DO10971-DQ10971
DS :aroon_sgn
=SI(ET(DS10970=1;DR10971 < 0)=VRAI;0;SI(ET(DS10970=0;DR10971 > =0)=VRAI ;1;DS10970))

sar_rabindranath

09 avril 2025 •11:11

Average True Range (ATR) : indicateur de volatilité
Indicateur technique développé par J. Welles Wilder. (créateur du RSI, du Parabolic SAR ou encore de l'ADX.
Calcul de l'ATR :

L'auteur a créé un concept : le "True Range (TR)" calculé chaque jour, puis il lui applique une moyenne mobile exponentielle sur 14 jours.
Calcul du True Range : le TR est le plus grand des écarts entre :

Le plus haut du jour - le plus bas du jour
Le plus haut du jour - la clôture de la veille, en valeur absolue
Le plus bas du jour - la clôture de la veille, en valeur absolue
ATR du jour = (ATR de la veille * 13 + TR du jour) / 14
l’ATR aide à visualiser les tendances de fond et fixer des stops de protection de façon rationnelle.
Excel : 7 colonnes de DT à DZ
NB j'utilise un ATR10

Constantes : DX3=10, DY3=18
DT : H-B
=C10971-D10971
DU : ABS(H-Clotn-1)
=ABS(C10971-E10970)
DV : ABS(B-Clotn-1)
=ABS(D10971-E10970)
DW : TR
=MAX(DT10971:DV10971)
DX : ATR10
=((DX10970*($DX$3-1))+DW10971)/$DX$3
DY : mma18_atr10
=MOYENNE(DECALER(DX10971;-$DY$3+1;0):DX10971)
DZ : atr_sgn
=SI(ET(DZ10970=1;DY10971 > DY10970)=VRAI;0;SI(ET(DZ10970=0;DY10971 < DY10970)=VRAI;1;DZ10970))
paramétrage perso : Vente si mma18_atr10 en hausse ; achat si mma18_atr10 en baisse

sar_rabindranath

09 avril 2025 •11:15

SuperTrend : indicateur mixte de tendance et de volatilité
Créé par le trader français Olivier Seban, le SuperTrend est un indicateur technique qui vise à détecter les tendances des cours.
C'est un outil utilisé par les analystes et notamment pour fixer des "stops" de protection.
Calcul

La première étape consiste à calculer l'ATR ("Average true Range" qui est une mesure de la volatilité) sur toute la période d'historique puis ensuite les deux bandes de l'indicateur :
Tendance haussière = (plus haut + plus bas) / 2 + c * ATR(n)
Tendance baissière = (plus haut + plus bas) / 2 - c * ATR(n)
Avec :
n : période de calcul de l'ATR, typiquement 10
c : coefficient permettant de pondérer la volatilité mesurée par l'ATR.
La formule standard utilise un coefficient de 3
Conclusion

Le Supertrend est particulièrement efficace pour suivre des grandes tendances et tenir la position tout du long sans sortir sur de petites corrections intermédiaires.
Du fait de sa sensibilité modérée, il ne se retournera pas aussitôt en raison de la volatilité des cours comme peuvent le faire d'autres indicateurs comme le SAR Parabolique par exemple.
Cette sensibilité à la volatilité peut d'ailleurs être affinée en réglant son coefficient (qui est de 3 en standard).
Son défaut, comme beaucoup d'indicateurs de tendance, est de ne pas être pertinent lors des phases de "trading range" quand le marché hésite en évoluant sans direction.
Dans ces cas-là, il génèrera de petites pertes sur des allers-retours. Par contre, elles seront largement compensées par l'avantage de pouvoir se laisser porter sur de grandes tendances de fond sans sortir trop tôt.
NB : Colonnes du tableur Excel de EA à EI (9 colonnes) considérées comme vides car elles contiennent le SuperTrend3 qui n’est pas assez sensible et que j'ai remplacé par le SuperTrend1,8 que je détaille ci-dessous.
Excel : 9 colonnes de EJ à ER dont 3 vides, EL à EN (compactage formules)

Constante : EJ3=1,8
EJ : up
=((C10971+D10971)/2)+($EJ$3*DX10971)
EK : dn
=((C10971+D10971)/2)-($EJ$3*DX10971)
EO : dn2
=SI(OU(EK10971 > EO10970;E10970 < EO10970);EK10971;EO10970)
EP : up2
=SI(OU(EJ10971 < EP10970;E10970 > EP10970);EJ10971;EP10970)
EQ :std1,8
=SI(ET(EQ10970=EP10970;E10971 < =EP10971);EP10971;SI(ET(EQ10970=EP10970;E10971 > =EP10971);EO10971;SI(ET(EQ10970=EO10970;E10971 > =EO10971);EO10971;SI(ET(EQ10970=EO10970;E10971 < =EO10971);EP10971;""))))
ER : std1,8_sgn
=SI(ET(E10971 > EQ10971;EQ10971 > 0)=VRAI;1;0)

sar_rabindranath

09 avril 2025 •11:18

Avec la rediffusion des épisodes manquants dans l'historique, vous disposez des épisodes 1 à 9 du coin des ATistes.
Je vous suggère d'en faire une copie si vous souhaitez les conserver !

Je n'envisage pas de faire une 2e rediffusion...
Bonne lecture

TopDown

09 avril 2025 •11:31

sar_rabindranath
😘

M1938142

09 avril 2025 •12:22

Un très grand MERCI
Bravo pour votre travail et votre sens du partage, respect

The-Great

14 juin 2025 •19:44

bonjour sar_rabindranath

pour le 13 juin j'ai

Williams
7659,137869,92185,24210,79-87,87892747-59,484674290


Aroon 7869,9 27659,131121,428571430100-78,571428570


ATR 54,5551,43105,98105,9879,86 43104491,278730641


SuperTrend 7830,1607597542,6492417671,1168667 830,1607597830,1607590


correct ?

sar_rabindranath

14 juin 2025 •20:04

13/06
Williams

76597870185211-87,88-59,480
Aroon

7869,927659,1311210100- 790
ATR

54,5551,43105,98105,9879,9391,461
SuperTrend_1,8

7830,287542,530 7670,977830,287830,280

sar_rabindranath

14 juin 2025 •20:06

Il faut tronquer après les chiffres significatifs

sar_rabindranath

14 juin 2025 •20:09

Bravo, vous êtes à 3 épisodes de la fortune !

The-Great

14 juin 2025 •20:14

sar_rabindranath

14 juin 2025 •20:09

Bravo, vous êtes à 3 épisodes de la fortune !

Excellent, j'aime votre humour 😉​😄

sar_rabindranath

14 juin 2025 •20:23

Humour ? Est-ce si sûr ?

50K€ placés à 30% l'an pendant 10 ans deviennent 689K€

The-Great

14 juin 2025 •21:12

sar_rabindranath

14 juin 2025 •20:23

Humour ? Est-ce si sûr ?

50K€ placés à 30% l'an pendant 10 ans deviennent 689K€

Oui... " il n'y a plus qu'à ..." comme on dit....
Avoir un bon outil c'est le début, ensuite faut encore bien l'utiliser...

The-Great

17 juin 2025 •20:27

bonsoir sar_rabindranath

Pour le supertrend_1,8, après avoir cherché et vérifié mes formules dans mon tableur, je trouve bizarre que
ma colonne EQ soit toujours vide
et ma colonne ER soit toujours à 0

voici mes valeurs pour le 16 juin 20225

EJ = 7882
EK = 7592,6
EO = 7670,97
EP = 7830,27
EQ vide
ER = 0

sar_rabindranath

17 juin 2025 •20:37

EQ n'est jamais vide.
L'erreur vient de la formule en EQ
Pour le 16/06 (ligne 11309 pour moi), le formule est
=SI(ET(EQ11308=EP11308;E11309 < =EP11309);EP11309;SI(ET(EQ11308=EP11308;E11309 > =EP11309);EO11309;SI(ET(EQ11308=EO11308;E11309 > =EO11309);EO11309;SI(ET(EQ11308=EO11308;E11309 < =EO11309);EP11309;""))))

valeur EQ 16/06 7830,28

sar_rabindranath

17 juin 2025 •20:39

pour que le post passe j'ai mis des espaces avant et après > et < : il faut les enlever

The-Great

17 juin 2025 •21:19

J'ai vérifié la formule EQ, tout est OK

Mais comme EQ dépend de EO et EP

Pour les 12 et 13/06 en EO j'ai 7670,975
Pour les 12 et 13/06 en EP j'ai 7830,2757

et toi stp ?

sar_rabindranath

17 juin 2025 •21:32

ok

The-Great

17 juin 2025 •21:35

bizarre je ne vois pour le moment, plus où chercher.... je te tiens au courant si je trouve quelquechose

sar_rabindranath

17 juin 2025 •21:40

il faut initialiser EO avec la même valeur que EK

The-Great

17 juin 2025 •21:41

ouf ... en réfléchissant sur la formule et changeant mes valeurs d'initialisation pour EO , EP et EQ,
j'ai maintenatnt EQ 16/06 7830,28

c'est en ordre , je continue avec l'épisode 7

merci

hankm

03 octobre 2025 •21:41

Bonsoir Sar, j'ai fait des copies de toutes vos postes "Coin des Atéistes" avec toutes les formules en cas de suppression. J'en suis au 15ème indicateur, le SuperTrend, et j'ai un souci avec la colonne EQ dont la formule me donne un blanc. Pour verification j'ai ce jour 03/10/25 (ligne 5580 pour moi) :

EJ 8211,22

EK 7926,38

EO 7926,37

EP 8202,64

EQ blanc

hankm

03 octobre 2025 •23:56

Problème réglé, je ne sais comment, mais j'ai intégré la formule sur la ligne du 16/06/25 pour verifier les valeurs avec celles de The Great

sar_rabindranath

04 octobre 2025 •02:24

Bonnsoir hankm,
EQ doit être à 7926,38 sur la ligne du 03/10/25
la formule est :
=SI(ET(EQ11387=EP11387;E11388 < =EP11388);EP11388;SI(ET(EQ11387=EP11387;E11388 >= EP11388);EO11388;SI(ET(EQ11387=EO11387;E11388 > =EO11388);EO11388;SI(ET(EQ11387=EO11387;E11388 < =EO11388);EP11388;""))))
J'ai mis des espaces avant et après sup et inf pour que ça passe
le 03/10 est la ligne 11388 pour moi
Bonne nuit

sar_rabindranath

04 octobre 2025 •02:33

Pour avoir blanc à chaque fois, c'est que vous étiez à la dernière hypothèse de la formule soit "" (tout à droite de la formule)
Il y avait donc probablement une erreur dans votre formule (un espace en trop par exemple)

sar_rabindranath

04 octobre 2025 •02:37

Plus que 7 indicateurs et Irma sera à vous...

Bravo vous avez fait 68,18% du travail
Vous n'êtes pas costaud qu'en musique !
Bon week-end

hankm

04 octobre 2025 •08:42

sar_rabindranath

04 octobre 2025 •02:37

Plus que 7 indicateurs et Irma sera à vous...

Bravo vous avez fait 68,18% du travail
Vous n'êtes pas costaud qu'en musique !
Bon week-end

Ha ha ! Vous êtes sympa Sar, avec Excel je ne fais que singer. Mais j'ai une caractéristique marquée (parfois c'est une qualité, parfois non) c'est que je n'aime pas commencer quelque chose sans la terminer. Bref, je suis têtu.

Bon weekend également!